【VBA】フォルダのサイズをエラー回避しながら取得するコード

Private fso As Scripting.FileSystemObject
Private Enum dType
    FILE = 1
    folder
End Enum

Private Sub Class_Initialize()
    gbCount = 0
    byteCount = 0
    Set fso = CreateObject("Scripting.FileSystemObject")
End Sub
Private Function getFolderObj(folderName As String) As folder
    
    Set getFolderObj = Nothing
    On Error Resume Next
    Set getFolderObj = fso.GetFolder(folderName)
    On Error GoTo 0

End Function

'************************************************
' フォルダサイズ取得メソッド(フォルダ名から）
'
Function getFolderSizeFromPath(folderName As String) As Variant
    Dim folderObj As folder
    
    Set folderObj = getFolderObj(folderName)
    If folderObj Is Nothing Then
        getFolderSizeFromPath = 0
    Else
        getFolderSizeFromPath = getFolderSize(folderObj)
    End If

End Function
'************************************************
' フォルダサイズ取得メソッド(Folderオブジェクトから)
'
Function getFolderSize(folderObj As folder) As Variant
    
    Dim size As Variant
    size = 0
    
    On Error GoTo sizeError
    ' sizeプロパティの取得
    size = folderObj.size
    
EndStep:
    On Error GoTo 0
    getFolderSize = size
    Exit Function
    

sizeError:
    ' sizeプロパティの取得失敗
    Dim fsize As Variant

    On Error GoTo sizeError2
    
    ' Filesプロパティの有効性チェック
    If checkObj(folderObj, dType.FILE) Then
        ' ファイルサイズのカウント
        Dim fl As FILE
        For Each fl In folderObj.Files
            fsize = fl.size
            size = size + fsize
        Next
    End If
    
    ' SubFoldersプロパティの有効性チェック
    If checkObj(folderObj, dType.folder) Then
        ' フォルダサイズのカウント
        Dim fo As folder
        For Each fo In folderObj.SubFolders
            fsize = getFolderSizeFromPath(fo.Path)
            size = size + fsize
        Next
    End If
    
    GoTo EndStep
    
sizeError2:
    'サイズ取得失敗 0として計算
    fsize = 0
    Resume Next
    
End Function
'************************************************
' サブフォルダサイズ取得メソッド(フォルダ名から）
'  戻り値:Dictionary key⇒フォルダ名 item⇒サイズ
Function getSubFolderSizeFromPath(folderName As String) As Variant
    Dim folderObj As folder
    
    Set folderObj = getFolderObj(folderName)
    If folderObj Is Nothing Then
        Set getSubFolderSizeFromPath = New Dictionary
    Else
        Set getSubFolderSizeFromPath = getSubFolderSize(folderObj)
    End If

End Function
'************************************************
' サブフォルダサイズ取得メソッド
'  戻り値:Dictionary key⇒フォルダ名 item⇒サイズ
Function getSubFolderSize(folderObj As folder) As Dictionary
    Dim dic As New Dictionary
        
     ' SubFoldersプロパティの有効性チェック
    If checkObj(folderObj, dType.folder) Then
        ' フォルダサイズのカウント
        On Error GoTo sizeError
        Dim fo As folder, fsize As Variant
        
        For Each fo In folderObj.SubFolders
            fsize = fo.size
            dic.Add Item:=fsize, Key:=fo.name
        Next
    End If

EndStep:
    On Error GoTo 0
    Set getSubFolderSize = dic
    Exit Function
    
sizeError:
     fsize = getFolderSizeFromPath(fo.Path)
     Resume Next
End Function
'************************************************
' FolderまたはFileオブジェクトの有効チェック
'
Private Function checkObj(fo As folder, ctype As dType) As Boolean
    Dim c As Object
    On Error GoTo er
    
    ' オブジェクトの取り出しチェック
    If ctype = dType.FILE Then
        Set c = fo.Files
    Else
        Set c = fo.SubFolders
    End If

    Dim count As Long
        ' countの取り出しチェック
    count = c.count
    checkObj = True
    
EndStep:
    On Error GoTo 0
    Exit Function
er:
    checkObj = False
    Resume EndStep
End Function

Sub test()
    Debug.Print Time

    Dim fs As New folderSize
    Debug.Print fs.getFolderSizeFromPath("C:\")

    Debug.Print Time
End Sub

16:19:03 
 670375117201 
16:23:19 

Sub test2()
    Debug.Print Time
    Dim fso As New Scripting.FileSystemObject
    Dim fs As New folderSize
    
    Debug.Print fs.getFolderSizeFromPath(fso.GetFolder("C:\"))

    Debug.Print Time
End Sub

Sub test3()
    Debug.Print Time
    
    Dim fs As New folderSize
    
    Dim dic As Dictionary
    Set dic = fs.getSubFolderSize("C:\")
    
    Dim name As Variant
    For Each name In dic
        Debug.Print name & ":" & dic.Item(name)
    Next name
    
    Debug.Print Time
    
End Sub

16:35:33 
$Recycle.Bin:18052881403
$WinREAgent:0
Config.Msi:0
Documents and Settings:0
Program Files:27824796327
Program Files (x86):290400502435
ProgramData:20619023347
Recovery:1109
Runtime:13989
System Volume Information:0
temp:2823224
Users:254708353929
Windows:44145166227
16:40:10 

Sub test4()
    Debug.Print Time
    
    Dim fso As New Scripting.FileSystemObject
    Dim fs As New folderSize
    
    Dim dic As Dictionary
    Set dic = fs.getSubFolderSize(fso.GetFolder("C:\"))
    
    Dim name As Variant
    For Each name In dic
        Debug.Print name & ":" & dic.Item(name)
    Next name
    
    Debug.Print Time
End Sub