【VBA】相対パスを絶対パスに変換する２つの方法

'
' 相対パスを絶対パス（フルパス）に変換
'
Function getFullPath(relativePath As String) As String

    Const PathSep As String = "\"
    
    ' ********* 1. カレントフォルダの取得
    Dim currentFolder As String

    If relativePath Like "?:\*" Then ' 引数はフルパス
        '  ※存在しないドライブも処理可能
        currentFolder = relativePath ' 引数をカレントフォルダとして扱う
        relativePath = ""
        
    ElseIf relativePath Like "?:*" Then  ' 引数はドライブで始まる
        '  ※存在しないドライブはエラー
        Dim rArray() As String
        rArray = Split(relativePath, ":")
        currentFolder = CurDir(rArray(0)) ' ドライブのカレントフォルダを取得
        relativePath = rArray(1)          ' 引数からドライブ削除
        
    Else
        currentFolder = CurDir      ' カレントフォルダを取得
    End If

    ' ********* 2.ドライブ文字を削除（記憶）する
    Dim currentArray() As String
    Dim driveText As String
    
    currentArray = Split(currentFolder, ":\")
    driveText = currentArray(0)
    
    ' 相対パスの先頭が\
    If relativePath Like "\*" Then
         currentArray(1) = "" ' ドライブ文字のみ残す
    End If
    
    ' ********* 3.4.カレントフォルダと相対パスを結合して分割
    Dim paths() As String
    paths = Split(currentArray(1) & PathSep & relativePath, PathSep)
    
    ' 結果格納用配列の確保
    Dim result() As String
    ReDim result(0 To UBound(paths))
    
    Dim pos As Integer: pos = 0 ' 結果配列の現在位
    
    ' ********* 5.配列のループ処理
    Dim name As Variant
    
    For Each name In paths
        name = Trim(name)
        If Len(name) > 0 Then
            Select Case name
                Case "."    ' 読み飛ばし
                Case ".."   ' 一つ戻る
                    pos = pos - 1
                    If pos < 0 Then pos = 0
                Case Else   ' 結果配列の末尾に追加
                    result(pos) = name
                    pos = pos + 1
            End Select
        End If
    Next
    
    ' ********* 6."\"で結合
    Dim resultPath As String
    resultPath = ""
    If pos > 0 Then
        ReDim Preserve result(pos - 1) ' 不必要な要素を削除
        resultPath = resultPath & Join(result, PathSep)
    End If
    
    ' ********* 7.ドライブ文字を結合
    getFullPath = driveText & ":\" & resultPath
    
End Function

Sub test()
    Debug.Print "****************"
    Debug.Print "【カレント】" & CurDir
    Debug.Print getFullPath("")
    Debug.Print getFullPath("abc")
    Debug.Print getFullPath("abc\def")
    Debug.Print getFullPath("..\abc\def")
    Debug.Print getFullPath("\abc\def\..\ccc\..\..\ddd")
    Debug.Print "****************"    
    Debug.Print "カレント(D):" & CurDir("d")
    Debug.Print getFullPath("d:")
    Debug.Print getFullPath("d:abc")
    Debug.Print getFullPath("d:abc\def")
    Debug.Print getFullPath("d:..\abc\def")
    Debug.Print getFullPath("d:\abc\def\..\ccc\..\..\ddd")
    Debug.Print "****************"
End Sub

****************
【カレント】C:\Users\xxx\Documents\project
C:\Users\xxx\Documents\project
C:\Users\xxx\Documents\project\abc
C:\Users\xxx\Documents\project\abc\def
C:\Users\xxx\Documents\abc\def
C:\ddd
****************
【カレント(D)】D:\test\folder1\data
D:\test\folder1\data
D:\test\folder1\data\abc
D:\test\folder1\data\abc\def
D:\test\folder1\abc\def
d:\ddd
****************

'
' 相対パスを絶対パス（フルパス）に変換
'
Function getFullPathUseFSO(relativePath As String) As String
    
    getFullPathUseFSO = CreateObject("Scripting.FileSystemObject") _
                            .GetAbsolutePathName(relativePath)
    
End Function

Sub test()
    Debug.Print "****************"
    Debug.Print "【カレント】" & CurDir
    Debug.Print getFullPathUseFSO("")
    Debug.Print getFullPathUseFSO("abc")
    Debug.Print getFullPathUseFSO("abc\def")
    Debug.Print getFullPathUseFSO("..\abc\def")
    Debug.Print getFullPathUseFSO("\abc\def\..\ccc\..\..\ddd")
    Debug.Print "****************"
    Debug.Print "カレント(D):" & CurDir("d")
    Debug.Print getFullPathUseFSO("d:")
    Debug.Print getFullPathUseFSO("d:abc")
    Debug.Print getFullPathUseFSO("d:abc\def")
    Debug.Print getFullPathUseFSO("d:..\abc\def")
    Debug.Print getFullPathUseFSO("d:\abc\def\..\ccc\..\..\ddd")
    Debug.Print "****************"
End Sub

****************
【カレント】C:\Users\xxx\Documents\project
C:\Users\xxx\Documents\project
C:\Users\xxx\Documents\project\abc
C:\Users\xxx\Documents\project\abc\def
C:\Users\xxx\Documents\abc\def
C:\ddd
****************
【カレント(D)】D:\test\folder1\data
D:\test\folder1\data
D:\test\folder1\data\abc
D:\test\folder1\data\abc\def
D:\test\folder1\abc\def
D:\ddd
****************