【VBA】ドライブ情報（容量、種類、ネットワーク共有名等）を取得する方法/GetDriveメソッドとDriveオブジェクト

Sub getDriveSample()
    Dim fso As New Scripting.FileSystemObject
    Dim driveInfo As drive
    
    Set driveInfo = fso.GetDrive("C")
    
    With driveInfo
        Debug.Print "容量: " & .TotalSize & "バイト"
        Debug.Print "空き容量: " & .FreeSpace & "バイト"
        Debug.Print "システム種別: " & .FileSystem
    End With
End Sub

容量: 524082098176バイト
空き容量: 48267239424バイト
システム種別: NTFS

Sub drivesSample()

    Dim fso As New Scripting.FileSystemObject
    Dim drv As drive
    
    Dim driveType() As Variant
    driveType = Array("不明", "リムーバブルデバイス", "固定ディスク", _
            "ネットワークドライブ", "光ディスクデバイス", "RAMディスク")
    
    For Each drv In fso.Drives
        With drv
            Debug.Print "ドライブ名: " & .DriveLetter
            Debug.Print "タイプ: " & driveType(.driveType)

            If .IsReady Then
                Debug.Print "システム種別: " & .FileSystem
                Debug.Print "容量: " & .TotalSize & "バイト"
                Debug.Print "空き容量: " & .FreeSpace & "バイト"
            Else
                Debug.Print "準備ができていません"
            End If
            Debug.Print vbCrLf
        End With
    Next drv

End Sub

ドライブ名: C
タイプ: 固定ディスク
システム種別: NTFS
容量: 524082098176バイト
空き容量: 48212729856バイト

ドライブ名: D
タイプ: 固定ディスク
システム種別: NTFS
容量: 1000203087872バイト
空き容量: 925569429504バイト

ドライブ名: E
タイプ: 光ディスクデバイス
準備ができていません

Dim driveObj as Drive
Set driveObj = fs.GetDrive( "d" )
driveObj.VolumeName = "new volume name"